package
{
 
	import flash.display.Bitmap;
	import flash.display.Sprite;
	import flash.events.Event;
 
	import org.papervision3d.cameras.Camera3D;
	import org.papervision3d.materials.BitmapMaterial;
	import org.papervision3d.materials.ColorMaterial;
	import org.papervision3d.materials.utils.MaterialsList;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.objects.special.DAEMC;
	import org.papervision3d.render.BasicRenderEngine;
	import org.papervision3d.scenes.Scene3D;
	import org.papervision3d.view.Viewport3D;
 
	public class Cow3d extends Sprite
	{
		private var scene:Scene3D;
		private var viewport:Viewport3D;
		private var camera:Camera3D;
		private var renderer:BasicRenderEngine;
 
		//將 DAE 檔案加入 FLASH
		[Embed(source = "cow.dae", mimeType = "application/octet-stream")]
  		private var COW_dae:Class;
  		//將 DAE 的貼圖也崁入 FLASH 中
  		[Embed(source = "cow.png")]    
  		private var COW_pic:Class; 
  		//這個是 DAE 模型的物件
  		private var cow_Object:DAEMC;
 
		public function Cow3d()
		{
			//初始化 3D 場景
			this.init3D();
			//初始化 3D 物件
			this.init3DObject();
		}
 
		private function init3D():void{
			//建立 3D 運鏡與場景
			this.viewport = new Viewport3D(530,380,false,true);
			this.addChild(this.viewport);
			this.renderer = new BasicRenderEngine();
			this.camera = new Camera3D();
			this.scene = new Scene3D();
			//this.camera.zoom = 2;
			//this.camera.focus = 150;
			this.camera.y = 400;
			//this.camera.rotationX = 45;
			//因為怕用到 STAGE 屬性，所以算圖必須要在 ADDED TO STAGE 之後才可以啟動
			this.addEventListener(Event.ADDED_TO_STAGE,onAddedToStage);
		}
		private function onAddedToStage(event:Event):void{
			this.addEventListener(Event.ENTER_FRAME,onEventRender3D);
		}
		private function onEventRender3D(event:Event):void{
			//算圖
			this.renderer.renderScene(this.scene,this.camera,this.viewport);
		}
		private function init3DObject():void{
			//把 DEA 檔案物件化
			var cow_dae:Object = new COW_dae();
			//貼圖圖片物件化
			var cow_pic:Bitmap = new COW_pic();
			//把圖片的 BITMAP DATA 轉為 3D貼圖材質
			var cow_skin:BitmapMaterial = new BitmapMaterial(cow_pic.bitmapData);
			//放入貼圖材質庫中
			var materials:MaterialsList = new MaterialsList();
			//加入材質庫 材質名稱 texture0
			materials.addMaterial(cow_skin,"texture0");
			//建立 DAEMC 物件 ( 自動撥放 , 名稱 , 每秒影格撥放速度 )
			this.cow_Object = new DAEMC(false,null,0);
			//讀取 DAE 模型 並且 貼上材質
			this.cow_Object.load(cow_dae,materials);
			//放大 100 倍
			this.cow_Object.scale = 100;
			//將 3D 物件加入場景
			this.scene.addChild(this.cow_Object);
 
			//建立環境平台
			var colorMaterial:ColorMaterial = new ColorMaterial(0x666666);
			colorMaterial.fillAlpha = 0.5;
			var plane:Plane = new Plane(colorMaterial,1000,1000);
			plane.rotationX = 90;
			this.scene.addChild(plane);
 
		}
 
		public function go():void{
			//前進   moveRight 是因為模型是朝右邊
			this.cow_Object.moveRight(10);
		}
		public function back():void{
			//後退   moveLeft 是因為模型是朝右邊
			this.cow_Object.moveLeft(10);
		}
		public function turnLeft():void{
			//左轉
			this.cow_Object.rotationY -= 5 ;
		}
		public function turnRight():void{
			//右轉
			this.cow_Object.rotationY += 5 ;
		}
 
	}
}

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="vertical" fontSize="14" creationComplete="init()" keyDown="keyActive(event)">
	<mx:Script>
		<![CDATA[
 
 
			private var obj3d:Cow3d = new Cow3d();
			private function init():void{
				this.show3dArea.addChild(this.obj3d);
			}
			private function keyActive(event:KeyboardEvent):void{
 
				switch(event.keyCode){
					case Keyboard.UP:
						this.obj3d.go();
						break;
					case Keyboard.DOWN:
						this.obj3d.back();
						break;
					case Keyboard.RIGHT:
						this.obj3d.turnRight();
						break;
					case Keyboard.LEFT:
						this.obj3d.turnLeft();
						break;
				}
			}
		]]>
	</mx:Script>
	<mx:Panel width="550" height="440" layout="absolute" title="跑跑牛犇車 :: 使用鍵盤上下左右控制牛車  design by corAusir">
		<mx:UIComponent id="show3dArea"/>
	</mx:Panel>
	<mx:Button label="前進" click="this.obj3d.go()"/>
	<mx:HBox>
		<mx:Button label="左轉" click="this.obj3d.turnLeft()"/>
		<mx:Button label="後退" click="this.obj3d.back()"/>
		<mx:Button label="右轉" click="this.obj3d.turnRight()"/>
	</mx:HBox>
 
</mx:Application>